it-swarm-tr.com

Bir pencereden başlık çubuğu, çerçeve vb. Kaldırmak için Windows programı?

Tam ekran yerine bilgisayar oyunları pencereli modda oynamayı seviyorum. Başlık çubuğuna, çerçeveye ve diğer UI önemsizlerine bakmayı sevmiyorum. Ayrıca masaüstümde pencerenin etrafında başka şeyler görmekten de hoşlanmıyorum. UI kromunu başka bir uygulamadan rastgele bir pencereden çıkaracak basit bir Windows programı var mı? Pencerenin altına siyah bir ekran koymak ve masaüstünü gizlemek için kolay bir yol için ekstra noktalar.

Not: Özellikle masaüstü boyutumdan daha küçük pencereleri ele almak istiyorum. Bir pencereyi tamamen masaüstü boyutunda yapan ve tüm UI dekorasyonları ekran dışı olacak şekilde konumlandırılmış çeşitli 'pencereli maksimize' seçenekleri vardır. (E.g .: ShiftWindow). Tüm süsleri masaüstü boyutundan daha küçük bir pencereden uzağa çıkarmaya çalışıyorum.

29
Nelson

Sadece voodoomsr'ın yorumunu okuduktan sonra amaçlarım için yaptığım küçük bir şey. Sol köşeye gitmesini sağlar ve tam çözünürlüğüme göre yeniden boyutlandırır. Daha önce olduğu gibi geri yükler. Aynı anda birden fazla uygulama ile kullanılamaz.

Teşekkürler voodoomsr

;-Caption
LWIN & LButton::
SetTitleMatchMode, 2
WinGetPos, X, Y, Width, Height, A
WinSet, Style, -0xC00000, A
WinMove,A,,0,0,1920,1080
return
;

;+Caption
LWIN & RButton::
WinSet, Style, +0xC00000, A
WinMove,A,,%X%,%Y%,%Width%,%Height%
Sleep, 1000
Sleep, 1000
return
;

DÜZENLE:

TBH Yeniden boyutlandırılmayan ancak hiçbir şey bulamayan pencereler için yararlı bir şey bulmaya çalıştım (mümkün olmadığını söyleyerek değil, bu aslında benim ilk Autohotkey betiğimdi).

Her neyse, gereksiz uykuları kaldırmak, Nelson'ın önerdiği stili kullanarak ve tek bir düğmeyle çalışmasını sağlamak için bazı değişiklikler yaptım, böylece çift tıklamak kaydedilen değişkenleri geçersiz kılmaz.

#SingleInstance force

; Exclude the desktop
; Note: Also excludes "My Computer" browsing windows.
;       Better detection might be needed to differentiate the parent Explorer "ahk_id" from child windows.
;       Also seems to disregard accidental Metro interface clicks (Win 8+)
#IfWinNotActive ahk_exe Explorer.exe

; Set your resolution (minus decorations like start bars if you wish to leave those on-screen.
w = 1920
h = 1080
w_wasted = 6 ; width used by resize bars
h_wasted = 29 ; width used by caption frame and resize bars

; Window to fullscreen
LWIN & LButton::
  SetTitleMatchMode, 2
  WinGet Style, Style, A

  ; 0xC40000 = WS_BORDER (0x800000) + WS_DLGFRAME (0x400000) + WS_SIZEBOX aka WS_THICKFRAME (0x040000)
  if(Style & 0xC00000) { ; if has WS_CAPTION. Ignore sizebox value.
    WinGetPos, X, Y, Width, Height, A
    WinSet, Style, -0xC40000, A ; removes attributes, including sizebox...doesn't do a strict subtraction
    WinMove,A,,0,0,w,h
  } else {
    WinSet, Style, +0xC40000, A
    ; Note: will set WS_SIZEBOX even if not previously present
    if(Width > w - w_wasted) { 
      Width := %w%-%w_wasted%
    }
    if(Height > h - h_wasted) {
      Height := %h%-%h_wasted%
    }
    WinMove,A,,%X%,%Y%,%Width%,%Height%
  }
  WinSet Redraw
  Return
14
Mikuz

sadece bu autohotkey betiğini kullanın:

;-Caption
LWIN & LButton::
WinSet, Style, -0xC00000, A
return
;

;+Caption
LWIN & RButton::
WinSet, Style, +0xC00000, A
return
;

autohotkey'i buradan indirebilirsiniz --- http://www.autohotkey.com/download/ . Dosyayı .ahk uzantılı kaydedin ve herhangi bir uygulama gibi çalıştırın.

Kullanımı:

başlık çubuğunu kaldırmak için LWindowButton + Sol tıklatma

başlık çubuğunu geri yüklemek için LWindowButton + Sağ tıklama

19
mjsr

here herhangi bir pencerenin başlık çubuğunu kaldırabilecek bir programdır. Bunu yapmak için WinExplorer ağacı görünümünde oyun penceresini 'Stil' sekmesine geçip WS_DLGFRAME adlı dosyayı işaretlemeniz gerekir.

6
Blza

AutoHotKey ve bir otomatik gizleme görev çubuğunu kullanarak.

LWin & f::

WinGet Style, Style, A
if(Style & 0xC40000) {
  WinSet, Style, -0xC40000, A
  WinMaximize, A 

} else {
  WinSet, Style, +0xC40000, A
  WinRestore, A
}
return

Neden WinMaxmize kullanıyorsunuz? Asd'ın cevabı yorumlarına bakınız.

3
weakish

CutAway Skrommel, istediğini yapabilir.

Cut Away

2
Richard

bunu HydrogenAudio forumlarında buldum:

İşte Foobar 2000'in pencere başlık çubuğu olmayan ekran görüntüsü:

enter image description here

Kullanılan program Flash Masaüstüleri (shareware) olarak adlandırılır.

Maalesef, hedefe ulaşmak için program ayarları üzerinde yoğunlaşmıyorlar, daha ziyade bir başlık çubuğu olmadan pencereleri hareket ettirme problemi üzerinde çalışıyorlar. WindowBlinds da belirtilmiştir.

1
Molly7244

Artık Windows kullanmıyorum, bu yüzden bunu test edemiyorum, ancak Borderless Gaming bu sorunu çözen umut verici görünen açık kaynaklı bir uygulama. Çalışan uygulamaların bir listesini gösterir ve pencereleri değiştirmek için bir tane seçmenizi sağlar.

0
Nelson

Kodlayabiliyorsanız ve Vista veya daha yeni bir sürümü çalıştırıyorsanız, uygulamaya bir DWM küçük resmi kaydeden bir program yapmak oldukça kolaydır ve o zaman bu küçük resimde yalnızca pencere içeriğini kenarlıksız göstermeyi seçebilirsiniz. Ayrıca, bu bindirme programından oyuna tüm girdileri bir şekilde iletmek zorundasınız ancak bu da çok karmaşık değil.

0
mmmmmm

Belirli bir pencereyle ilgili sorun yaşıyordum; @ zayıf yöntemiyle ve Mikuz'un çerçevesiyle, büyütülmüş bir pencere için doğru pencere boyutunu alabiliyordu, ancak doğru konuma gitmiyordu.

İşte benim ahk çözümüm

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       Win2000+
; Author:         mpag derived from Mikuz
;
; Script Function:
;    Window to "supermaximized". mpag solution from http://superuser.com/q/38687/319748
;    If you want fullscreen (no toolbars) try replacing calls to function WinSuperMax with WinFullscreen
; This script may still be in development
; Bugs:
;    1) Doesn't display scrollbars in standard maximized screen if it lost them upon supermax (unless you restore and re-maximize)
;    2) If supermaxing a background window that has menus within the Caption bar (e.g. firefox), you functionally just maximize but lose the min/restore/close buttons. Probably has something to do with the Style value.
; Memory Management/Clarity:
;    3) Doesn't clear G_ variable values before each run. if the number of monitors (virtual or otherwise) reduces, values for higher monitor numbers will still be set, but MonCount should still be valid and restrict use. also picks first match.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#SingleInstance force

SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

MonGetCoords() {
  global ; for setting
  SysGet G_MonCount, MonitorCount
  loop %G_MonCount% {
    SysGet G_MonWA%A_Index%, MonitorWorkArea, %A_Index%
    SysGet G_MonFS%A_Index%, Monitor, %A_Index%
  }
}

GetMon4xy(ByRef x="", ByRef y="", ByRef m="") {
  global ; getting
  local l:=0, u:=0
  m := 0 ; even if sent, we want to clear it
  loop %G_MonCount% {
    l := G_MonFS%A_Index%Left
    u := G_MonFS%A_Index%Right
    if x not between %l% and %u%
      continue 
    l := G_MonFS%A_Index%Top
    u := G_MonFS%A_Index%Bottom
    if y not between %l% and %u%
      continue 
    m := A_Index
    break
  }
}

WinSetSz(d, mp) {
  global
  local l, r, t, b
  l := %mp%Left
  r := %mp%Right
  t := %mp%Top
  b := %mp%Bottom
  WinMove ahk_id %d%, , l, t, r - l + 1, b - t + 1
  return
}

WinSuperMax(d, m) {
  mp = G_MonWA%m% ; the text of the name of the pointer
  WinSetSz(d, mp)
  return
}

WinFullscreen(d, m) {
  mp = G_MonFS%m%
  WinSetSz(d, mp)
  return
}

; Exclude the desktop
; Note: Also excludes "My Computer" browsing windows.
;       Better detection might be needed to differentiate the parent Explorer "ahk_id" from child windows.
;       Also seems to disregard accidental Metro interface clicks (Win 8+).
;       May wish to verify that not only is Explorer not the active window, but it wasn't the clicked-in window.

#IfWinNotActive ahk_exe Explorer.exe

LWIN & LButton::
RCtrl & LButton::
  SetTitleMatchMode, 2

; monitor bounds and clicked window hwnd
  cm = %A_CoordModeMouse% ; not autoset in older AHK, but shouldn't matter as default is Screen
  CoordMode Mouse, Screen
  MouseGetPos mpx, mpy, d ; was d := WinExist("A") but that would go for the active window, rather than the clicked-in-window
  CoordMode Mouse, %cm%
  MonGetCoords()
  GetMon4xy(mpx, mpy, mpm)

; toggle the style
  WinGet Style, Style, ahk_id %d%
; 0xC40000 = WS_BORDER (0x800000) + WS_DLGFRAME (0x400000) + WS_SIZEBOX or WS_THICKFRAME (0x040000)
  if(Style & 0xC00000) { ; if has WS_CAPTION (WS_BORDER+WS_DLGFRAME) we want to supermax it
    v%d%decs := Style & 0x040000 ; decorations, specifically WS_SIZEBOX
    WinGet v%d%mm, MinMax, ahk_id %d% ; -1=min, 0=normal, 1=max
    WinSet Style, -0xC40000, ahk_id %d% ; removes most window decoration, including WS_SIZEBOX if applicable
; if a "normal" window, get the coords and maximize. If minimized, maximize. If maximized, make sure correctly positioned
    if(!v%d%mm) { ; normal window
      WinGetPos v%d%x, v%d%y, v%d%w, v%d%h, ahk_id %d%
    } if(v%d%mm < 1) { ; normal or minimized
      WinMaximize ahk_id %d% ; set flag to maximized to preserve windows' restore button functionality upon un-supermax to maximized screen
    } 
    WinSuperMax(d, mpm) ; it is now supermaximized. Now make sure it's positioned correctly
  } else { ; it's super-maximized already, so need to restore it to former position.
    if (v%d%decs) {
      WinSet Style, +0xC40000, A ; set WS_SIZEBOX and WS_CAPTION
    } else {
      WinSet Style, +0xC00000, A ; set only WS_CAPTION
    }
    if(v%d%mm = 0) { ; not either previously Maximized nor previously Minimized
      WinRestore ahk_id %d% ; restore standard window + set MinMax flag to non-maxxed 
    } else {
      WinSuperMax(d, mpm) ; Maximized flag should still be set
    }
  }
  WinSet Redraw
;  ListVars
  Return
0
mpag